A*%%TS  SD  20100330  145939  SCROY       REL-V5R4M0  5722-WDS
     A********************************************************************
     A*  DISPLAY NAME - SC0190DF                                         *
     A*                                                                  *
     A*  FUNCTION    - This display WORKS WITH softcode users            *
     A*                                                                  *
     A*  PROGRAMMER   - STEVE CROY            10/18/06                   *
     A********************************************************************
     A********************************************************************
     A*                   MODIFICATION LOG                               *
     A*                                                                  *
     A*   DATE   PROGRAMMER      DESCRIPTION                             *
     A*                                                                  *
     A********************************************************************
     A* Include PRINT and INVITE at the file level to allow  PRINT
     A* function and device file time out coding in applications
     A*
     A*%%EC
     A                                      DSPSIZ(24 80 *DS3)
     A                                      REF(*LIBL/SCUSRSPF)
     A                                      PRINT
     A                                      INDARA
     A                                      CF01
     A                                      CF02
     A                                      CA03
     A                                      CF04
     A                                      CF05
     A                                      CF06
     A                                      CF07
     A                                      CF08
     A                                      CF09
     A                                      CF10
     A                                      CF11
     A                                      CF12
     A                                      CF13
     A                                      CF14
     A                                      CF15
     A                                      CF16
     A                                      CF17
     A                                      CF18
     A                                      CF19
     A                                      CF20
     A                                      CF21
     A                                      CF22
     A                                      CF23
     A                                      CF24
     A                                      ROLLUP(90)
     A                                      ROLLDOWN(91)
     A                                      HOME
     A                                      HELP
     A          R SC019001
     A                                      BLINK
     A                                      OVERLAY
     A            JOBNAM        10A  O  1  2COLOR(BLU)
     A            PRGNAM        10A  O  1 13COLOR(BLU)
     A                                  1 27'iSoftwerks Incorporated'
     A                                  1 61SYSNAME
     A                                      COLOR(BLU)
     A                                  1 70DATE
     A                                      EDTCDE(Y)
     A                                      COLOR(BLU)
     A            USER          10A  O  2  2COLOR(BLU)
     A            JOBNBR         6A  O  2 13COLOR(BLU)
     A            Z$SEQ1        30A  O  2 24DSPATR(HI)
     A            FMTNAM         8A  O  2 61COLOR(BLU)
     A                                  2 70TIME
     A                                      COLOR(BLU)
     A                                  4  4'Type in option, press enter.'
     A                                      DSPATR(HI)
     A                                      COLOR(BLU)
     A                                  4 48'Position to:'
     A            Z$SCAN        10A  B  4 61CHANGE(22)
     A                                      DSPATR(HI)
     A            Z$OPT1        60A  O  5 12COLOR(BLU)
     A            Z$OPT2        60A  O  6 12COLOR(BLU)
     A                                  8  2'Op User       Status    Eff Date E-
     A                                      xp Date              Email         -
     A                                              '
     A                                      DSPATR(HI)
     A          R SC0190S1                  SFL
     A  58                                  SFLNXTCHG
     A            Z$RRN1         4S 0H
     A            Z$DBRN         9S 0H
     A            Z$OPT          2A  B  9  2DSPATR(HI)
     A  30                                  DSPATR(PR)
     A            MSUSRP    R        O  9  5REFFLD(MSUSRP)
     A            Z$STAT         9A  O  9 16
     A            Z$EFDT         6Y 0O  9 26EDTCDE(Y)
     A            Z$XDTE         6Y 0O  9 35EDTCDE(Y)
     A            Z$MAIL        35   O  9 44
     A          R SC0190C1                  SFLCTL(SC0190S1)
     A                                      SFLSIZ(0013)
     A                                      SFLPAG(0012)
     A                                      BLINK
     A                                      OVERLAY
     A  51                                  SFLDSP
     A  50                                  SFLDSPCTL
     A  53                                  SFLINZ
     A  55                                  SFLDLT
     A  52                                  SFLCLR
     A  54                                  SFLEND(*MORE)
     A                                      CSRLOC(#ROW       #COL)
     A            #ROW           3S 0H
     A            #COL           3S 0H
     A            Z$RRN2         4S 0H      SFLRCDNBR(CURSOR)
     A            Z$KEY1        60   O 22 11COLOR(BLU)
     A            Z$KEY2        60   O 23 11COLOR(BLU)
     A*----------------------------------------------------------------
     A* SUBFILE MESSAGE QUEUE
     A*----------------------------------------------------------------
     A          R SC0190S2                  SFL
     A                                      SFLMSGRCD(24)
     A            MSGKEY                    SFLMSGKEY
     A            PRGNAM                    SFLPGMQ
     A          R SC0190C2                  SFLCTL(SC0190S2)
     A                                      SFLSIZ(2) SFLPAG(1)
     A  59                                  SFLEND
     A  59                                  SFLDSP
     A                                      SFLDSPCTL
     A N59                                  SFLCLR
     A  59                                  SFLINZ
     A            PRGNAM                    SFLPGMQ